Electrónica de Potencia/Módulos de regulación de continua/Troceador Clase E

Troceador Clase E

Introducción

Convertidor de puente completo montado con transistores bipolares de puerta aislada (IGBT)

También llamado troceador de cuatro cuadrantes ya que la corriente en la carga puede ser tanto positiva como negativa, al igual que ocurre con el voltaje de la misma.

Al circuito de la figura se le conoce como convertidor de puente completo. Puede funcionar como troceador (regulación CC-CC) o como inversor (conversión CC-AC) y aunque la topología de tipo puente es la misma para ambas aplicaciones, el tipo de control varía de una a otra.

La regulación CC se consigue regulando el ancho de banda de la señal a una frecuencia fija y el dispositivo de conmutación por lo general suele ser un transistor BJT,MOSFET o IGBT.

Funcionamiento en los 4 cuadrantes

Se pueden combinar dos troceadores de clase C (2 cuadrantes) para formar un troceador de clase E.

El troceador de puente completo se utiliza para regular voltaje en accionamientos motrices de corriente continua, en siguiente figura observamos los 4 cuadrantes de funcionamiento junto con los dispositivos que son operativos en los distintos cuadrantes.

-En el 1º cuadrante: V,I,E son positivas (con V > E) consiguiendo un par motor y una velocidad positivos.

-En el 2º cuadrante: La fuerza contra electro motriz E permanece positiva. Como V < E , la corriente es negativa lo que implica que el motor funciona en sentido directo pero con par motor negativo (frenado regenerativo a favor de la marcha)

-En el 3º cuadrante: V y E son negativas de manera que V > E (En magnitud), teniendo una corriente negativa y con ello un par motor y una velocidad negativas.

-En el 4º cuadrante: V y E son negativas pero esta vez V > E (En magnitud), teniendo una corriente positiva y con ello un par motor positivo con la energía fluyendo del motor a la fuente.

Ejemplos de aplicación:

-Ejemplo 1:

Podemos mantener abierta una “diagonal” (por ejemplo, S1 y S2 abiertos) para que el ciclo de trabajo lo realicen los otros dos interruptores (S3 y S4) abriéndose y cerrándose a la vez.

De esta manera cuando S3 y S4 están cerrados, cae voltaje negativo sobre la carga mientras que la corriente circuila en sentido negativo.
Cuando S3 y S4 se abren, la corriente que atraviesa la carga la carga puede circular por los diodos D1 y D2 siendo negativa durante todo el periodo mientras que el voltaje en la carga ahora es positivo, funcionando así en el 2º y 3º cuadrante.

Con este método podemos tener dos posibles troceadores de tipo D cada uno de los cuales controlaría un sentido de giro distinto de un motor.

Podríamos conseguir trabajar en el 1º y 4º cuadrante si realizamos la misma secuencia cambiando S1 y S2 por S3 y S4 (Al igual que los diodos D1 y D2 por D3 y D4 respectivamente).

-Simulación en PSpice AD:

TROCEADOR EN PUENTE COMPLETO (2º y 3º cuadrante)

v1 1 0 100
x1 1 2 SCRDC PARAMS:T=0 TD=0 TP=0 F=1000
d1 2 1 dmod
x2 3 0 SCRDC PARAMS:T=0 TD=0 TP=0 F=1000
d2 0 3 dmod
x3 1 3 SCRDC PARAMS:T=1 TD=180 TP=179 F=1000
d3 3 1 dmod
x4 2 0 SCRDC PARAMS:T=1 TD=180 TP=179 F=1000
d4 0 2 dmod
L 2 4 10M
R 4 5 10
VC 5 3 30
.model dmod d(is=2.2e-15 bv=1800)
.LIB LEP2016.LIB
.TRAN 10u 12M 10M 10u
.probe

-Subcircuito Interruptor

.SUBCKT SCRDC 1 2 PARAMS: T=1 TD=0 TP=90 F=1000
ST 1 5 3 0 SMOD
DT 5 2 DMOD
VG 3 0 PULSE (0 {10*T} {TD/(360*F)} 0 0 {TP/(360*F)} {1/F})
RG 3 0 10MEG
.MODEL SMOD VSWITCH(RON=0.001 ROFF=10E8 VON=5 VOFF=2)
.MODEL DMOD D
.ENDS SCRDC

En la siguiente gráfica podemos ver la tensión en la carga

Observando la gráfica de la intensidad podemos notar que es negativa en todo el periodo, aunque el voltaje cambie de positivo a negativo (3º y 4º cuadrante)

-Ejemplo 2:

Otro método, similar al anterior, sería mantener una diagonal abierta (S3 y S4) pero de manera que el ciclo de trabajo lo realice únicamente un “interruptor” (Por ejemplo S1, manteniéndose S2 cerrado durante todo el periodo).

De esta manera el sentido de la intensidad (y por tanto del giro de un motor conectado al circuito) lo define la diagonal activa; ya que cuando conduzcan S1 y S2 el tanto el voltaje como la intensidad que circula por la carga son positivos.
En el momento en que S1 se abra, la corriente circulará por D4 manteniendo su sentido pero haciendo que la caida de tensión en la carga sea 0.

-Simulación en PSpice AD:

TROCEADOR EN PUENTE COMPLETO

v1 1 0 100
x1 1 2 SCRDC PARAMS:T=1 TD=0 TP=179 F=1000
d1 2 1 dmod
x2 3 0 SCRDC PARAMS:T=1 TD=0 TP=359 F=1000
d2 0 3 dmod
x3 1 3 SCRDC PARAMS:T=0 TD=0 TP=0 F=1000
d3 3 1 dmod
x4 2 0 SCRDC PARAMS:T=0 TD=0 TP=0 F=1000
d4 0 2 dmod
L 2 4 10M
R 4 5 10
VC 5 3 30
.model dmod d(is=2.2e-15 bv=1800)
.LIB LEP2016.LIB
.TRAN 10u 12M 10M 10u
.options itl4=50 abstol=10m reltol=10m
.probe

-Subcircuito Interruptor

.SUBCKT SCRDC 1 2 PARAMS: T=1 TD=0 TP=90 F=1000
ST 1 5 3 0 SMOD
DT 5 2 DMOD
VG 3 0 PULSE (0 {10*T} {TD/(360*F)} 0 0 {TP/(360*F)} {1/F})
RG 3 0 10MEG
.MODEL SMOD VSWITCH(RON=0.001 ROFF=10E8 VON=5 VOFF=2)
.MODEL DMOD D
.ENDS SCRDC

En la siguiente gráfica podemos ver la tensión en la carga:

Vemos también la intensidad en la carga, que en este caso es siempre positiva:

-Ejemplo 3:

Por último, otro método sería alternar las diagonales.
De esta forma el circuito puede funcionar como un inversor (si el ciclo de trabajo es 0,5), teniendo alternativamente una diferencia de potencial en el motor de +V , -V.
Cuando conducen S1 y S2 cae en el motor una diferencia de potencial positiva y circula por el una corriente en sentido negativo.
Al conmutar los interruptores, comienzan a conducir S3 y S4 manteniendo el sentido de la intensidad pero siendo ahora la diferencia de potencial en los bornes del motor neativa.

-Simulación en PSpice AD:

TROCEADOR EN PUENTE COMPLETO

v1 1 0 100
x1 1 2 SCRDC PARAMS:T=1 TD=0 TP=179 F=1000
d1 2 1 dmod
x2 3 0 SCRDC PARAMS:T=1 TD=0 TP=179 F=1000
d2 0 3 dmod
x3 1 3 SCRDC PARAMS:T=1 TD=180 TP=179 F=1000
d3 3 1 dmod
x4 2 0 SCRDC PARAMS:T=1 TD=180 TP=179 F=1000
d4 0 2 dmod
L 2 4 10M
R 4 5 10
VC 5 3 30
.model dmod d(is=2.2e-15 bv=1800)
.LIB LEP2016.LIB
.TRAN 10u 12M 10M 10u
.probe

-Subcircuito Interruptor

.SUBCKT SCRDC 1 2 PARAMS: T=1 TD=0 TP=90 F=1000
ST 1 5 3 0 SMOD
DT 5 2 DMOD
VG 3 0 PULSE (0 {10*T} {TD/(360*F)} 0 0 {TP/(360*F)} {1/F})
RG 3 0 10MEG
.MODEL SMOD VSWITCH(RON=0.001 ROFF=10E8 VON=5 VOFF=2)
.MODEL DMOD D
.ENDS SCRDC

En la siguiente gráfica podemos ver la tensión en la carga:

Vemos también que la intensidad en este caso oscila entre valores negativos y positivos: