SPARQL/5

Esta página contiene ejemplos de consultas enfocadas en videojuegos

Videojuegos cuya licencia es GPLv3 (también llamados, juegos libres)

SELECT ?item ?itemLabel ?itemDescription {
  ?item 
    # instancia de (P31) videojuego (Q7889)
    wdt:P31 wd:Q7889;
    # licencia (P275) GPLv3 (Q10513445)
    wdt:P275 wd:Q10513445.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Géneros más populares de videojuegos con licencia GPLv3

SELECT
  ?genre
  ?genreLabel
  (COUNT(?genre) AS ?count)
{
  ?item 
    # instancia de (P31) videojuego (Q7889)
    wdt:P31 wd:Q7889;
    # licencia (P275) GPLv3 (Q10513445)
    wdt:P275 wd:Q10513445;
    # género (P136) sandbox (Q25397095)
    wdt:P136 ?genre.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?genre ?genreLabel
ORDER BY DESC(?count)

Videojuegos con alguna licencia libre. Mostrar la fecha de publicación y los géneros de ellos.

SELECT DISTINCT
  ?fechaDePublicación
  ?licenciaLabel
  ?item
  ?itemLabel
  ?itemDescription
  ?géneros
WITH {
  SELECT DISTINCT ?item {
    ?licencia
      wdt:P31/wdt:P279* wd:Q5975031.
    ?item 
      wdt:P31/wdt:P279* wd:Q7889;
      wdt:P275 ?licencia.
  }
} AS %videojuegos
WITH {
  SELECT
    ?item
    (GROUP_CONCAT(?géneroEtiqueta; SEPARATOR = ", ") AS ?géneros)
  {
    INCLUDE %videojuegos.
    ?item wdt:P136 ?género.
    ?género rdfs:label ?géneroEtiqueta.
    FILTER(LANG(?géneroEtiqueta) = "en")
  }
  GROUP BY ?item
} AS %géneros
{
  INCLUDE %videojuegos.
  OPTIONAL{INCLUDE %géneros.}
  OPTIONAL{?item wdt:P577 ?fechaDePublicación}
  OPTIONAL{?item wdt:P275 ?licencia}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ASC(?itemLabel)