Manual del estudiante de Ingeniería en Sistemas de UTN/Simulación/Software de simulación de eventos discretos/Ejercicio 5 GPSS
Problema 5
[editar]A un negocio de ventas de hamburguesas llegan clientes cada 60 +/- 30 segundos. Los clientes hacen el pedido y pagan en la única caja del local. El tiempo de atención en la caja es de 30 +/- 15 segundos. Allí se les entrega un número con el cual deben retirar sus pedidos frente a un mostrador atendido por tres personas. Los tiempos de preparación de los pedidos varía según sean para ser consumidos en el local (90 +/- 10 seg.) o para llevar (120 +/- 20 seg.). De los clientes que llegan al negocio, un 20% compra hamburguesas para llevar, el resto consume en el lugar. El que consume en el lugar tiene 2 opciones: el salón de planta baja (salón rojo) o el del primer piso (salón azul). Un 30% se dirige al salón rojo cuya capacidad es de 30 personas y el resto al salón azul cuya capacidad es de 40 personas. El tiempo de permanencia en cada uno de los salones depende de la hora del día:
| Horario | Salón Rojo (X1) | Salón Azul (X2) |
| 11 a 12 | 20 +/- 15 min | 30 +/- 10 min |
| 12 a 13 | 30 +/- 15 min | 40 +/- 10 min |
| 13 a 14 | 35 +/- 15 min | 45 +/- 10 min |
| 14 a 15 | 20 +/- 15 min | 35 +/- 10 min |
Simular de 11 a 15 horas, y obtener
- Tiempo de permanencia en el negocio.
- Tiempo en cola en la caja.
- Cada 15 minutos, la cantidad de gente en cola frente al mostrador.
- Cada 30 minutos, la cantidad de personas en el Salón Rojo y en el Azul (separadamente).
Solución 1
[editar]tiempo TABLE M1,500,500,30 ;tiempo de permanencia
enQCaja QTABLE colaCaja,60,60,20 ;tiempo de espera en caja
cantCola TABLE Q$colaMost,5,5,20
cantRojo TABLE S$salonR,3,3,10
cantAzul TABLE S$salonA,4,4,10
lugar FUNCTION RN1,D2
0.20,1/1,2
tiempoR FUNCTION AC1,D4
3600,1200/7200,1800/10800,2100/14400,1200
tiempoA FUNCTION AC1,D4
3600,1800/7200,2400/10800,2700/14400,2100
salonR STORAGE 30
salonA STORAGE 40
mostrador STORAGE 3
GENERATE 60,30
ASSIGN donde,FN$lugar
QUEUE colaCaja
SEIZE caja
DEPART colaCaja
ADVANCE 30,15
RELEASE caja
QUEUE colaMost
TEST E P$donde,1,enlugar
ENTER mostrador
DEPART colaMost
ADVANCE 120,20
LEAVE mostrador
TABULATE tiempo
TERMINATE
enlugar ENTER mostrador
DEPART colaMost
ADVANCE 90,10
LEAVE mostrador
TRANSFER 0.30,irAzul,irRojo
irRojo ENTER salonR
ADVANCE FN$tiempoR,900
LEAVE salonR
TABULATE tiempo
TERMINATE
irAzul ENTER salonA
ADVANCE FN$tiempoR,600
LEAVE salonA
TABULATE tiempo
TERMINATE
GENERATE 900
TABULATE cantCola
TERMINATE
GENERATE 1800
TABULATE cantRojo
TABULATE cantAzul
TERMINATE
GENERATE 14400
TERMINATE 1
Solución 2 (con uso de función discreta SNA)
[editar]tiempo TABLE M1,500,500,30 ;tiempo de permanencia
enQCaja QTABLE colaCaja,60,60,20 ;tiempo de espera en caja
cantCola TABLE Q$colaMost,5,5,20
cantRojo TABLE S$salonR,3,3,10
cantAzul TABLE S$salonA,4,4,10
consume FUNCTION RN1,D2
0.20,lleva/1,nolleva
tiempoR FUNCTION AC1,D4
3600,1200/7200,1800/10800,2100/14400,1200
tiempoA FUNCTION AC1,D4
3600,1800/7200,2400/10800,2700/14400,2100
salonR STORAGE 30
salonA STORAGE 40
mostrador STORAGE 3
GENERATE 60,30
QUEUE colaCaja
SEIZE caja
DEPART colaCaja
ADVANCE 30,15
RELEASE caja
QUEUE colaMost
TRANSFER ,FN$consume
lleva ENTER mostrador
DEPART colaMost
ADVANCE 120,20
LEAVE mostrador
TABULATE tiempo
TERMINATE
nolleva ENTER mostrador
DEPART colaMost
ADVANCE 90,10
LEAVE mostrador
TRANSFER 0.30,irAzul,irRojo
irRojo ENTER salonR
ADVANCE FN$tiempoR,900
LEAVE salonR
TABULATE tiempo
TERMINATE
irAzul ENTER salonA
ADVANCE FN$tiempoR,600
LEAVE salonA
TABULATE tiempo
TERMINATE
GENERATE 900
TABULATE cantCola
TERMINATE
GENERATE 1800
TABULATE cantRojo
TABULATE cantAzul
TERMINATE
GENERATE 14400
TERMINATE 1