SPARQL/72

Esta página contiene una plantilla de consulta para obtener los lexemas con la mayor cantidad de una propiedad dada en un lenguaje dado.

Esta plantilla es utilizada por

• Lexema con la mayor cantidad de formas en un lenguaje dado
• Lexema con la mayor cantidad de sentidos en un lenguaje dado

SELECT
  ?lexema
  ?lemma
  ?conteo
WITH {
  SELECT
    *
  {
    VALUES ?parametroLengua {<<lengua>>}.
    VALUES ?parametroPropiedad {<<propiedad>>}.
  }
} AS %parametros
WITH {
  SELECT
    ?lexema
    (COUNT(DISTINCT ?valor) AS ?conteo)
  {
    INCLUDE %parametros.

    ?lexema
      dct:language ?parametroLengua;
      ?parametroPropiedad ?valor.
  }
  GROUP BY ?lexema
} AS %conteo
WITH {
  SELECT
    (MAX(?conteo) AS ?maxConteo)
  {
    INCLUDE %conteo.
  }
} AS %maxConteo
WITH {
  SELECT
    ?lexema
    ?conteo
  {
    INCLUDE %conteo.
    INCLUDE %maxConteo.
    FILTER(?conteo = ?maxConteo)
  }
} AS %lexemasConMaxConteo
{
  INCLUDE %lexemasConMaxConteo.
  ?lexema wikibase:lemma ?lemma.
}